Jak exportovat e-mailové adresy na základě konkrétní domény v aplikaci Outlook?

Pokud chcete exportovat e-mailové adresy s konkrétní doménou ze všech kontaktů v aplikaci Outlook, přečtěte si prosím tento návod, který vám pomůže použít kód VBA pro extrahování všech e-mailových adres v konkrétní doméně do textového souboru, jak je znázorněno na obrázku níže .

Exportujte e-mailové adresy na základě konkrétní domény v aplikaci Outlook pomocí kódu VBA

Chcete-li extrahovat všechny e-mailové adresy s konkrétní doménou ze všech kontaktů, proveďte prosím následující kroky:

1. Vytvořte nový textový soubor a pojmenujte jej, viz snímek obrazovky:

2. Podržte ALT + F11 klávesy pro otevření Microsoft Visual Basic pro aplikace okno.

3. Potom klepněte na tlačítko Vložit > Modula vložte následující kód do okna modulu.

Kód VBA: Export e-mailových adres na základě konkrétní domény

Dim GDomain As String
Dim GFileSystem As Object
Dim GFilePath As String
Dim GFileObj As Object
Private Declare PtrSafe Function ShellExecute Lib "shell32.dll" Alias "ShellExecuteA" (ByVal hWnd As Long, _
  ByVal ipOperation As String, ByVal lpFile As String, _
  ByVal lpParameters As String, ByVal lpDirectory As String, _
  ByVal nShowCmd As Long) As Long

Sub ExportListOfEmailAddressesInSpecificDomain()
'Updateby ExtendOffice
Dim xStore As Store
Dim xFolder As Folder
On Error Resume Next
GDomain = InputBox("Enter domain(@***.com):", "Kutools for Outlook")
If Len(GDomain) <> 0 Then
  GFilePath = "C:\Users\skyyang\Desktop\Email Addresses with specific domain.txt" 'Specify the file path
  Set GFileSystem = CreateObject("Scripting.FileSystemObject")
  Set GFileObj = GFileSystem.CreateTextFile(GFilePath, True)
  For Each xStore In Application.Session.Stores
    For Each xFolder In xStore.GetRootFolder.Folders
      If xFolder.DefaultItemType = olContactItem Then
        Call ProcessFolders(xFolder)
      End If
    Next
  Next
  GFileObj.Close
  ShellExecute 0&, vbNullString, GFilePath, vbNullString, vbNullString, 1
End If
End Sub

Sub ProcessFolders(ByVal Fld As Outlook.Folder)
Dim xContactItems As Items
Dim I As Long
Dim xContact As ContactItem
Dim xSubFolder As Folder
On Error Resume Next
Set xContactItems = Fld.Items
For I = xContactItems.Count To 1 Step -1
  If xContactItems(I).Class = olContact Then
    Set xContact = xContactItems(I)
    If InStr(xContact.Email1Address, GDomain) > 0 Then
      GFileObj.WriteLine (xContact.Email1Address & vbCrLf)
    ElseIf InStr(xContact.Email2Address, GDomain) > 0 Then
      GFileObj.WriteLine (xContact.Email2Address & vbCrLf)
    ElseIf InStr(xContact.Email3Address, GDomain) > 0 Then
      GFileObj.WriteLine (xContact.Email3Address & vbCrLf)
    End If
  End If
Next
If Fld.Folders.Count > 0 Then
  For Each xSubFolder In Fld.Folders
    If xSubFolder.DefaultItemType = olContactItem Then
      Call ProcessFolders(xSubFolder)
    End If
  Next
End If
End Sub

4. A pak stiskněte F5 klíč ke spuštění tohoto kódu. Zobrazí se okno s výzvou, zadejte prosím e-mailovou doménu, na základě které chcete exportovat e-mailové adresy, viz snímek obrazovky:

5. Potom klepněte na tlačítko OK a všechny e-mailové adresy v konkrétní doméně jsou extrahovány do textového souboru najednou, viz snímek obrazovky: