Rozdělte textový řetězec na konkrétní znak v buňce v aplikaci Excel
Tento kurz vysvětluje, jak rozdělit textový řetězec na konkrétní znak do samostatných buněk sloupců pomocí vzorců v aplikaci Excel.
Jak rozdělit textový řetězec na konkrétní znak v buňce v aplikaci Excel?
Předpokládejme, že máte ve sloupci B seznam textových řetězců jako snímek obrazovky níže a chcete rozdělit texty na znak „-“ a odeslat je do tří samostatných sloupců. V tomto případě vám níže uvedené vzorce mohou udělat laskavost.
Obecné vzorce
Obecný vzorec pro rozdělení levého textu
=LEFT(text_string,FIND("Char", text_string)-1)
Obecný vzorec pro rozdělení prostředního textu
=MID(text_string, FIND("Char", text_string) + 1, FIND("Char", text_string,FIND("Char", text_string)+1) - FIND("Char", text_string) - 1)
Obecný vzorec pro rozdělení správného textu
=RIGHT(text_string,LEN(text_string) - FIND("Char", text_string, FIND("Char", text_string) + 1))
Argumenty výše uvedených vzorců
Textový řetězec: Textový řetězec, ze kterého chcete rozdělit text;
Char: Znak, na kterém rozdělíte text.
Jak používat tyto vzorce?
Nejprve rozdělte první textový řetězec podle konkrétního znaku
1. Vyberte prázdnou buňku k odeslání výsledku. Zde vyberu C3.
2. Zadejte do ní následující vzorec a stiskněte vstoupit klíč. A pak přetáhněte buňku s levým vzorcem úplně dolů a použijte ji na další buňky.
=LEFT(B3,FIND("-",B3)-1)
Za druhé rozdělte prostřední textový řetězec na konkrétní znak
1. Vyberte prázdnou buňku, například D3, aby se výsledek zobrazil.
2. Zadejte do ní následující vzorec a stiskněte vstoupit klíč. Vyberte buňku výsledku, přetažením úchytu výplně dolů použijte vzorec na další buňky.
=MID(B3, FIND("-",B3) + 1, FIND("-",B3,FIND("-",B3)+1) - FIND("-",B3) - 1)
Nakonec rozdělte poslední textový řetězec na konkrétní znak
1. Vyberte prázdnou buňku, například E3, aby se výsledek zobrazil.
2. Zadejte do ní následující vzorec a stiskněte vstoupit klíč. Vyberte buňku výsledku, přetažením úchytu výplně dolů použijte vzorec na další buňky.
=RIGHT(B3,LEN(B3) - FIND("-", B3, FIND("-", B3) + 1))
Nyní byl textový řetězec v každé buňce sloupce B rozdělen na tři části.
Tipy: Pokud chcete pouze rozdělit textový řetězec na dvě části na základě konkrétního znaku, po rozdělení první části pomocí výše uvedeného LEVÉHO vzorce můžete použít níže uvedený PRAVÝ vzorec a extrahovat druhou část, jak je znázorněno níže.
=RIGHT(B3,LEN(B3)-FIND("-",B3))
Jak tyto vzorce fungují?
=LEFT(B3,FIND("-",B3)-1)
- FIND("-",B3): Funkce FIND vrací počáteční pozici znaku „-“ v textovém řetězci KTE-Jan-359. Výsledek je 4.
- LEFT(B3,4-1): Funkce LEFT extrahuje 3 znaky (4-1 = 3) z levé strany textového řetězce KTE-Jan-359. Výsledkem je KTE.
Poznámka: Protože první znak „-“ je na 4. pozici textového řetězce, je třeba odečíst 1, aby se vyloučil z extrakce.
=MID(B3, FIND("-",B3) + 1, FIND("-",B3,FIND("-",B3)+1) - FIND("-",B3) - 1)
- FIND("-",B3) + 1: Funkce FIND vrací počáteční pozici znaku „-“ v textovém řetězci KTE-Jan-359. Zde je výsledek 4.
Poznámka: Jelikož je první znak „-“ na 4. pozici textového řetězce, je třeba přidat 1 až 4, abychom za ním extrahovali texty, a nakonec skončíme na 4 + 1 = 5. - FIND("-",B3,FIND("-",B3)+1) zde se zobrazuje jako FIND ("-", KTE-Jan-359,4 + 1): Funkce Najít najde pozici znaku "-" počínaje od 5. znaku v KTE-Jan-359. A vrátí výsledek jako 8.
- MID(B3, 5, 8 - 4 - 1): MID (KTE-Jan-359,5,3), což znamená, že funkce MID extrahuje 3 počet znaků počínaje od 5. znaku v textovém řetězci KTE-Jan-359. A výsledkem je Jan.
=RIGHT(B3,LEN(B3) - FIND("-", B3, FIND("-", B3) + 1))
- LEN(B3): Funkce LEN vypočítá celkovou délku textového řetězce KTE-Jan-359 a vrátí výsledek jako 11.
- FIND("-",B3,FIND("-",B3)+1): Funkce Najít najde pozici znaku „-“ počínaje od 5. znaku v KTE-Jan-359. A vrátí výsledek jako 8.
- RIGHT(B3,11 - 8)): Funkce RIGHT extrahuje 3 (11-8) znaků z pravé strany KTE-Jan-359. Zde je výsledek 359.
Související funkce
Funkce Excel LEFT
Funkce LEFT extrahuje daný počet znaků z levé strany zadaného řetězce.
Funkce FIND FIND
Funkce FIND se používá k vyhledání řetězce v jiném řetězci a vrací počáteční pozici řetězce uvnitř jiného.
Funkce Excel MID
Funkce MID se používá k vyhledání a vrácení konkrétního počtu znaků ze středu zadaného textového řetězce.
Funkce Excel RIGHT
Funkce RIGHT extrahuje určitý počet znaků z pravé strany textového řetězce.
Funkce Excel LEN
Funkce Excel LEN vrací počet znaků v textovém řetězci.
Související vzorce
Rozdělte rozměry na dvě části v aplikaci Excel
Tento článek vysvětluje, jak používat vzorce k rozdělení dimenzí v buňce na dvě části bez jednotek (jednotlivé délky a šířky).
Oddělte čísla od měrných jednotek
Tento článek vysvětluje, jak pomocí vzorce oddělit čísla od jednotek měření.
Rozdělte text a čísla do buňky v aplikaci Excel
Pokud chcete rozdělit text a čísla v buňce na různé buňky sloupců pomocí vzorců, tento návod vám udělá laskavost.
Rozdělte text s oddělovačem do buňky v aplikaci Excel
V tomto článku poskytujeme podrobného průvodce, který vám pomůže rozdělit text v buňce pomocí konkrétního oddělovače v aplikaci Excel.
Nejlepší kancelářské nástroje produktivity
Kutools pro Excel - pomůže vám vyniknout před davem
Kutools pro Excel se může pochlubit více než 300 funkcemi, Zajištění toho, že to, co potřebujete, je jen jedno kliknutí...
Záložka Office - Povolte čtení a úpravy na záložkách v Microsoft Office (včetně Excelu)
- Jednu sekundu přepnete mezi desítkami otevřených dokumentů!
- Snižte stovky kliknutí myší každý den, sbohem s myší rukou.
- Zvyšuje vaši produktivitu o 50% při prohlížení a úpravách více dokumentů.
- Přináší efektivní karty do Office (včetně Excelu), stejně jako Chrome, Edge a Firefox.
