Note: The other languages of the website are Google-translated. Back to English

vynikat SUMPRODUCT funkce

V aplikaci Excel lze funkci SUMPRODUCT použít k vynásobení dvou nebo více sloupců nebo polí dohromady a následnému získání součtu produktů. Ve skutečnosti je SUMPRODUCT užitečná funkce, která může pomoci spočítat nebo sčítat hodnoty buněk s více kritérii, jako je funkce COUNTIFS nebo SUMIFS. Tento článek představí syntaxi funkce a několik příkladů pro tuto funkci SUMPRODUCT.


 Syntaxe:

Syntaxe funkce SUMPRODUCT v aplikaci Excel je:

=SUMPRODUCT (array1, [array2], ...)

 argumenty:

  • array1: Požadované. První pole nebo rozsah buněk, které chcete znásobit a poté přidat.
  • array2: Volitelné. Druhé pole nebo rozsah buněk, které chcete znásobit a poté přidat.

Poznámky:

  • 1. Pokud jsou ve vašem rozsahu nečíselné hodnoty, SUMPRODUCT s nimi zachází jako s nulami.
  • 2. Pokud pole nebo rozsahy mají různý počet řádků a sloupců, funkce SUMPRODUCT vrátí #HODNOTA! chyba.
  • 3. Pokud jsou v polích logické testy, vytvoří hodnoty PRAVDA a NEPRAVDA. Ve většině případů je budete muset převést na 1 a 0 pomocí dvojitého unárního operátoru (-).
  • 4. Funkce SUMPRODUCT dokáže zpracovat až 255 argumentů v aplikaci Excel 2007 a novějších verzích a pouze 30 argumentů v dřívějších verzích aplikace Excel.
  • 5. SUMPRODUCT nepodporuje zástupné znaky.

 Návrat:

Vrátí výsledek vynásobeného a sečteného pole.


 Příklady:

Příklad 1: Základní použití funkce SUMPRODUCT

Základní použití SUMPRODUCT je znásobit dva sloupce a poté je sečíst, například máte následující data obrazovky, nyní chcete znásobit objednávku a jednotkovou cenu a poté sečíst všechny výsledky násobení dohromady, abyste získali Celková cena.

Při řešení tohoto úkolu použijte následující vzorec:

=SUMPRODUCT(B2:B7,C2:C7)

Vysvětlení: Tento vzorec SUMPRODUCT(B2:B7,C2:C7) = B2*C2+B3*C3+B4*C4+B5*C5+B6*C6+B7*C7.

A pak stiskněte vstoupit klíč, buňky ve sloupci B se vynásobí odpovídajícími buňkami ve stejné řadě sloupce C a výsledky se sečtou. Viz screenshot:


Příklad 2: Součet buněk s více kritérii s funkcí SUMPRODUCT

Kromě funkce SUMIFS, která umožňuje sčítat hodnoty buněk na základě více podmínek, může funkce SUMPRODUCT také rychle a snadno vyřešit tuto úlohu.


Případ 1: Součet hodnot buněk, pokud obsahuje konkrétní text v jiném sloupci

Předpokládejme, že máte tabulku dat, jak je uvedeno níže, nyní chcete vypočítat celkovou cenu, kterou je produkt KTE a jmenuje se David, jak byste to mohli udělat pomocí vzorce SUMPRODUCT v aplikaci Excel?

1. Zadejte nebo zkopírujte některý z níže uvedených vzorců do prázdné buňky:

=SUMPRODUCT(--(A2:A12="KTE"), --(B2:B12="David"), D2:D12)
=SUMPRODUCT((A2:A12="KTE")*(B2:B12="David")*D2:D12)
  • Tipy: Ve výše uvedeném vzorci:
  • A2: A12 = "KTE": je první rozsah kritérií a kritéria, podle kterých chcete sečíst.
  • B2: B12 = "David": je druhý rozsah kritérií a kritéria, podle kterých chcete sečíst.
  • D2: D12: je rozsah součtu, ve kterém chcete sečíst hodnoty buněk.

2. Poté stiskněte vstoupit klíč k získání výsledku, jak potřebujete:


Případ 2: Součet buněk s více kritérii s logikou OR

Chcete-li sečíst buňky na základě více kritérií s logikou OR, měli byste použít symbol plus (+), abyste spojili více podmínek dohromady v rámci funkce SUMPRODUCT.

Například chci sečíst celkovou cenu produktu KTE a KTO ve sloupci A, jak je uvedeno níže:

Do prázdné buňky použijte následující vzorec:

=SUMPRODUCT((A2:A12="KTE")+(A2:A12="KTO"), C2:C12)

A pak stiskněte vstoupit klíč, byla vypočítána celková cena produktu KTE a KTO, viz screenshot:


Případ 3: Součet buněk s více kritérii s logikou OR a AND

V některých situacích možná budete muset sečíst buňky logikou OR i AND současně. Funkce SUMPRODUCE také může tuto úlohu snadno vyřešit.

Hvězdička (*) se používá jako operátor AND.

Symbol plus (+) se používá jako operátor OR.

Podívejme se na příklad, pro součet celkové ceny, který produkt je KTE a KTO, když je prodej větší než 200.

Měli byste zkopírovat nebo zadat následující vzorec:

=SUMPRODUCT((B2:B12>200)*((A2:A12="KTE")+(A2:A12="KTO"))*C2:C12)

Pak stiskněte tlačítko vstoupit klíč k získání výsledku, jak potřebujete:


Příklad 3: Počítání buněk s více kritérii pomocí funkce SUMPRODUCT

Obecně tato funkce SUMPRODUCT nám také může pomoci počítat buňky s více kritérii v aplikaci Excel. Stejně jako hodnoty součtu stačí z vzorce odebrat argument sum_range.


Případ 1: Počítání buněk s více kritérii pomocí logiky AND

Tady chci spočítat buňky, jejichž produktem je KTE a prodej je větší než 200. Použijte prosím některý z níže uvedených vzorců:

=SUMPRODUCT(--(A2:A12="KTE"), --(B2:B12>200))
=SUMPRODUCT((A2:A12="KTE")*(B2:B12>200))
  • Tipy: Ve výše uvedeném vzorci:
  • A2: A12 = "KTE": je první rozsah kritérií a kritéria, podle kterých chcete počítat.
  • B2: B12> 200: je druhý rozsah kritérií a kritéria, podle kterých chcete počítat.

A pak stiskněte vstoupit klíč k získání čísla výsledku:


Případ 2: Počítání buněk s více kritérii s logikou OR

Pro spočítání počtu produktů KTE a KTO ve sloupci A použijte tento vzorec:

=SUMPRODUCT((A2:A12="KTE")+(A2:A12="KTO"))

A pak stiskněte vstoupit klíč k získání čísla produktu KTE a KTO. Viz screenshot:


Případ 3: Počítání buněk s více kritérii s logikou OR a AND

Chcete-li spočítat počet produktů KTE a KTO, jejichž prodej je větší než 200, měli byste použít následující vzorec:

=SUMPRODUCT((B2:B12>200)*((A2:A12="KTE")+(A2:A12="KTO")))

Poté stiskněte vstoupit klíč k získání požadovaného počtu výsledků:


Příklad 4: Vypočítejte vážený průměr pomocí funkce SUMPRODUCT

Normálně můžeme rychle a snadno vypočítat průměr dosahu buněk. Pokud však chcete vypočítat průměr ze seznamu hodnot s různými úrovněmi relevance, znamená to vypočítat vážený průměr. Neexistuje žádná přímá funkce pro jeho získání v aplikaci Excel. Funkce SUMPRODUCT vám ale může pomoci se s tím vypořádat.

Například mám pro studenta tabulku statistik známek, každý úkol má jinou váhu, jak je ukázáno níže.

Pro výpočet váženého průměru použijte následující vzorec:

=SUMPRODUCT(B2:B6, C2:C6) / SUM(C2:C6)

Vysvětlení: Tento vzorec: SUMPRODUCT(B2:B6, C2:C6) / SUM(C2:C6) = (B2*C2+B3*C3+B4*C4+B5*C5+B6*C6)/(C2+C3+C4+C5+C6)

A pak stiskněte vstoupit klíč, vážený průměr byl vypočítán najednou, viz screenshot:


 Další články s funkcí SUMPRODUCT:

  • Počítat konkrétní hodnotu napříč více pracovními listy
  • Předpokládejme, že mám několik pracovních listů, které obsahují následující data, a nyní chci získat počet výskytů konkrétní hodnoty „Excel“ z těchto pracovních listů. Jak mohu spočítat konkrétní hodnoty na více pracovních listech?
  • Vypočítejte vážený průměr v aplikaci Excel
  • Například máte nákupní seznam s cenami, váhami a částkami. Průměrnou cenu můžete snadno vypočítat pomocí funkce PRŮMĚR v aplikaci Excel. Ale co když vážená průměrná cena? V tomto článku představím metodu výpočtu váženého průměru a metodu výpočtu váženého průměru, pokud splníte konkrétní kritéria v aplikaci Excel.

Nejlepší kancelářské nástroje produktivity

Kutools pro Excel - pomůže vám vyniknout před davem

Rádi byste svou každodenní práci dokončili rychle a dokonale? Kutools pro Excel přináší 300 výkonných pokročilých funkcí (kombinace sešitů, součet podle barvy, rozdělení obsahu buněk, převod data a tak dále...) a ušetří vám 80 % času.

  • Navrženo pro 1500 pracovních scénářů, pomůže vám vyřešit 80 % problémů s Excelem.
  • Omezte každý den tisíce kliknutí na klávesnici a myš a ulehčete svým unaveným očím a rukám.
  • Staňte se odborníkem na Excel za 3 minuty. Už si nemusíte pamatovat žádné bolestivé vzorce a kódy VBA.
  • 30denní neomezená bezplatná zkušební verze. 60denní záruka vrácení peněz. Bezplatný upgrade a podpora po dobu 2 let.
Pás karet aplikace Excel (s nainstalovaným programem Kutools pro Excel)

Záložka Office - Povolte čtení a úpravy na záložkách v Microsoft Office (včetně Excelu)

  • Jednu sekundu přepnete mezi desítkami otevřených dokumentů!
  • Snižte stovky kliknutí myší každý den, sbohem s myší rukou.
  • Zvyšuje vaši produktivitu o 50% při prohlížení a úpravách více dokumentů.
  • Přináší efektivní karty do Office (včetně Excelu), stejně jako Chrome, Firefox a Nový Internet Explorer.
Snímek obrazovky aplikace Excel (s nainstalovanou kartou Office)
Komentáře (0)
Zatím žádné hodnocení. Buďte první, kdo ohodnotí!
Zatím zde nejsou žádné komentáře

Sociální sítě

Copyright © 2009 - www.extendoffice.com. | Všechna práva vyhrazena. Poháněno ExtendOffice. | |. | Sitemap
Microsoft a logo Office jsou ochranné známky nebo registrované ochranné známky společnosti Microsoft Corporation ve Spojených státech a / nebo jiných zemích.
Chráněno Sectigo SSL