Přejít k hlavnímu obsahu

Prozkoumejte nové, Bezplatná verze Kutools pro Outlook ještě dnes!

 

Snadno počítejte jedinečné a odlišné hodnoty – 7 příkladů

Autor: Xiaoyang Naposledy změněno: 2024-08-06

Normálně jsou v Excelu jedinečné hodnoty hodnoty, které se v seznamu objeví pouze jednou bez jakýchkoli duplicit, a odlišné hodnoty jsou všechny různé hodnoty (jedinečné hodnoty + 1. duplicitní výskyty). Při práci na velké datové sadě možná budete muset spočítat počet jedinečných a odlišných hodnot mezi duplikáty ze seznamu buněk, jak je uvedeno níže. Tento tutoriál představí několik rychlých triků pro počítání jedinečných a odlišných hodnot v Excelu.

Počítejte jedinečné hodnoty nebo odlišné hodnoty v seznamu

Počítejte jedinečné hodnoty v Excelu

Počítejte různé hodnoty (jedinečné a 1. duplicitní výskyty) v Excelu

Stáhněte si ukázkový soubor

Počítejte jedinečné odlišné hodnoty

Počítejte jedinečné hodnoty v Excelu

Tato část bude hovořit o některých příkladech vzorců pro počítání počtu jedinečných hodnot, včetně textů a čísel v seznamu.

Počítejte jedinečné hodnoty pomocí vzorců

Předpokládejme, že mám seznam jmen, který obsahuje některá duplicitní jména v seznamu jmen. Nyní potřebuji získat pouze počet jedinečných jmen (které jsou vyplněny žlutou barvou), jak je uvedeno níže:

vzorek dat

Chcete-li tento problém vyřešit, může vám pomoci následující maticový vzorec:

Krok 1: Zadejte vzorec

Zadejte nebo zkopírujte níže uvedený vzorec do prázdné buňky, kde chcete vytisknout výsledek:

=SUM(IF(COUNTIF(A2:A12,A2:A12)=1,1,0))
 Pozor: Ve výše uvedeném vzorci, A2: A12 je seznam dat, který chcete považovat za jedinečný.

Krok 2: Stiskněte Ctrl + Shift + Enter klíče pro získání správného výsledku:

Počítejte jedinečné hodnoty pomocí vzorce

Tipy:

  1. Pokud váš seznam buněk obsahuje některé další typy dat, jako jsou čísla, logické hodnoty, chybové hodnoty atd., při použití výše uvedeného vzorce získá počet jedinečných hodnot bez ohledu na typ dat.
  2. Pokud seznam dat obsahuje prázdné buňky, tento vzorec prázdné buňky vyloučí.
  3. Na počítat pouze jedinečné textové hodnoty pokud existují jiné typy dat, použijte níže uvedený maticový vzorec a stiskněte Ctrl + Shift + Enter klávesy pro vrácení výsledku: 
    =SUM(IF(ISTEXT(A2:A12)*COUNTIF(A2:A12,A2:A12)=1,1,0))
  4. Na počítat pouze jedinečná čísla ze seznamu buněk, který obsahuje jakýkoli typ dat, použijte prosím následující maticový vzorec a stiskněte Ctrl + Shift + Enter klávesy pro vrácení výsledku: 
    =SUM(IF(ISNUMBER(A2:A12)*COUNTIF(A2:A12,A2:A12)=1,1,0))

Počítejte jedinečné hodnoty pomocí několika kliknutí pomocí Kutools pro Excel

Může pro vás být bolestivé pamatovat si vzorce, až je budete příště potřebovat použít. Ale pokud máte Kutools pro Excel, S jeho Počítejte jedinečné hodnoty možnost volby Pomocník vzorců, výsledek získáte pouze několika kliknutími. Viz níže ukázka:

  1. Klepnutím na buňku zobrazíte výsledek;
  2. Povolte tuto funkci kliknutím Kutools > Pomocník vzorců > Pomocník vzorců > Statistický > Počítat jedinečné hodnoty;
  3. Vyberte seznam dat > OK.
    Počítejte jedinečné hodnoty pomocí kutoolů
Tipy:
  1. Chcete-li použít tuto funkci, měli byste stáhnout a nainstalovat za prvé.
  2. Auto Pomocník vzorců funkce shromažďuje více než 40 běžně používaných vzorců, jako např Extrahujte jedinečné hodnoty, Extrahujte buňky s jedinečnými hodnotami (zahrňte první duplikáty), Spočítejte počet hodnot oddělených čárkou, Součet založený na stejném textu, a více...

Počítejte jedinečné hodnoty v Excelu 365/2021 pomocí vzorců

Pokud používáte Excel 365 nebo Excel 2021, existuje nová UNIKÁTNÍ funkce, která vám může pomoci vytvořit jednodušší vzorce pro počítání jedinečných hodnot v sadě dat.

Chcete-li například spočítat počet jedinečných jmen v rozsahu A2:A12, zadejte prosím následující vzorec:

Krok 1: Zkopírujte nebo zadejte níže uvedený vzorec

=IFERROR(ROWS(UNIQUE(A2:A12,,TRUE)), 0)
Pozor: V tomto vzorci A2: A12 je seznam dat, který chcete počítat jedinečné hodnoty.

Krok 2: Stiskněte vstoupit klíč k získání výsledku:

Počítejte jedinečné hodnoty v Excelu 365/2021 pomocí vzorce

Tipy:

  1. Pokud seznam dat obsahuje jiné typy dat, jako je text, čísla, logické hodnoty, chybové hodnoty atd., získá tento vzorec počet jedinečných hodnot bez ohledu na typ dat.
  2. Výše uvedený vzorec bude počítat jedinečné hodnoty včetně prázdných buněk, pokud chcete mezery vyloučit, použijte prosím níže uvedený vzorec a stačí stisknout vstoupit klíč: 
    =SUM(IF(COUNTIF(A2:A12,A2:A12)=1,1,0))

Počítejte různé hodnoty (jedinečné a 1. duplicitní výskyty) v Excelu

Abych spočítal různé hodnoty (jedinečné hodnoty a 1. duplicitní výskyty) v seznamu buněk, uvedu zde další vzorce k dosažení tohoto úkolu.

Počítejte různé hodnoty pomocí vzorců

V aplikaci Excel můžete použít kterýkoli z níže uvedených vzorců a vrátit počet odlišných hodnot.

Krok 1: Zadejte některý z níže uvedených vzorců

Formula 1: Po zadání vzorce stiskněte vstoupit klíč.

=SUMPRODUCT(1/COUNTIF(A2:A12,A2:A12))

Formula 2: Po zadání vzorce stiskněte Ctrl + Shift + Enter klíče.

=SUM(1/COUNTIF(A2:A12,A2:A12))
Pozor: V těchto vzorcích A2: A12 je seznam dat, který chcete počítat různé hodnoty.

Výsledek:

Počítejte různé hodnoty pomocí vzorce

Tipy:

  1. Pokud seznam dat obsahuje jiné typy dat, jako jsou čísla, logické hodnoty, chybové hodnoty atd., tento vzorec získá odlišné hodnoty bez ohledu na typ dat.
  2. Při použití výše uvedeného vzorce získáte chybovou hodnotu #DIV/0, pokud seznam dat obsahuje prázdné buňky. Chcete-li opravit a ignorovat prázdné buňky, měli byste použít jeden z níže uvedených vzorců:
    Formula 1: Po zadání vzorce stiskněte vstoupit klíč. 
    =SUMPRODUCT((A2:A12<>"")/COUNTIF(A2:A12,A2:A12&""))
    Formula 2: Po zadání vzorce stiskněte Ctrl + Shift + Enter klíče. 
    =SUM(IF(A2:A12<>"",1/COUNTIF(A2:A12, A2:A12), 0))

    Počítat odlišné hodnoty vylučují prázdné buňky se vzorcem

  3. Na získat pouze počet různých textových hodnot v seznamu dat použijte níže uvedený maticový vzorec a stiskněte Ctrl + Shift + Enter klíče k získání výsledku: 
    =SUM(IF(ISTEXT(A2:A12),1/COUNTIF(A2:A12, A2:A12),""))
  4. Na počítat pouze odlišné číselné hodnoty, použijte prosím následující maticový vzorec a stiskněte Ctrl + Shift + Enter klíče k získání výsledku: 
    =SUM(IF(ISNUMBER(A2:A12),1/COUNTIF(A2:A12, A2:A12),""))

Počítejte různé hodnoty pomocí několika kliknutí pomocí Kutools pro Excel

Pokud potřebujete vzorce v sešitu používat často, může pro vás být bolestivé zapamatovat si vzorce, až je budete potřebovat použít příště. Ale pokud máte Kutools pro Excel, S jeho Počítání buněk s jedinečnými hodnotami (včetně prvního duplikátu) možnost volby Pomocník vzorců, můžete získat výsledek pouze několika kliknutími. Viz níže ukázka:

  1. Klepnutím na buňku zobrazíte výsledek;
  2. Povolte tuto funkci kliknutím Kutools > Pomocník vzorců > Statistický > Počítejte jedinečné buňky s jedinečnými hodnotami (zahrňte první duplikát);
  3. Vyberte seznam dat > OK.
    Počítejte odlišné hodnoty pomocí kutoolů
Tipy:
  1. Chcete-li použít tuto funkci, měli byste stáhnout a nainstalovat za prvé.
  2. Auto Pomocník vzorců funkce shromažďuje více než 40 běžně používaných vzorců, jako např Extrahujte jedinečné hodnoty, Extrahujte buňky s jedinečnými hodnotami (zahrňte první duplikáty), Spočítejte počet hodnot oddělených čárkou, Součet založený na stejném textu, a více...

Počítejte odlišné hodnoty pomocí kontingenční tabulky

V Excelu může kontingenční tabulka také pomoci získat počet odlišných hodnot ze seznamu dat, proveďte prosím následující kroky:

Krok 1: Vytvořte kontingenční tabulku

  1. Vyberte seznam dat a klepněte na tlačítko Vložit > Kontingenční tabulka z pásu karet, viz snímek obrazovky:
    vytvořit kontingenční tabulku pro vybraná data
  2. Ve vyskočené Kontingenční tabulka z dialogového okna tabulky nebo rozsahu:
    (1). Vyberte nový list nebo existující list, kam chcete umístit kontingenční tabulku;
    (2). Pak zkontrolujte Přidejte tato data do datového modelu checkbox.
    (3). Pak klikněte OK .
    nastavit možnosti v kontingenční tabulce z dialogového okna tabulky nebo rozsahu

Krok 2: Uspořádejte pole a vyberte možnost Odlišný počet

  1.  A Pole kontingenční tabulky se zobrazí podokno, přetáhněte jej jména pole do Hodnoty oblast, viz ukázka níže:
    Uspořádejte pole pro otočení
  2. Poté klikněte na tlačítko Počet jmen rozevírací seznam a vyberte Nastavení hodnotového pole, viz screenshot:
    klepněte na možnost Nastavení pole
  3. A pak, a Nastavení hodnotového pole otevře se dialogové okno, vyberte Zřetelný počet ze seznamu pod Shrnout hodnotu podle kartu a klepněte na tlačítko OK tlačítko, viz screenshot:
    vyberte možnost Odlišný počet

Výsledek:

Vytvořená kontingenční tabulka nyní zobrazí odlišný počet datového seznamu, jak je znázorněno na obrázku níže:

Výsledek kontingenční tabulky pro počítání různých hodnot

Tipy:

  1. Pokud aktualizujete zdrojová data, abyste získali nejnovější počet, stačí kliknout pravým tlačítkem na kontingenční tabulku a vybrat Obnovit volba.
  2. Tento Zřetelný počet Tato možnost je dostupná pouze v Excelu 2013 a novějších verzích.

Počítejte různé hodnoty v Excelu 365/2021 pomocí vzorců

V Excelu 365 nebo Excelu 2021 můžete použít novou funkci UNIQUE s normální funkcí COUNTA k vytvoření snadného vzorce.

Zkopírujte nebo zadejte níže uvedený vzorec do prázdné buňky a stiskněte vstoupit klíč k získání výsledku:

=COUNTA(UNIQUE(A2:A12))
Pozor: V tomto vzorci A2: A12 je seznam dat, který chcete počítat odlišné hodnoty.

Počítejte různé hodnoty v Excelu 365/2021 pomocí vzorce

Tipy:

  1. Pokud seznam dat obsahuje jiné typy dat, jako je text, čísla, logické hodnoty, chybové hodnoty atd., bude tento vzorec počítat počet odlišných hodnot bez ohledu na typ dat.
  2. Výše uvedený vzorec bude počítat odlišné hodnoty včetně prázdných buněk, pokud chcete mezery vyloučit, použijte níže uvedený vzorec a stiskněte vstoupit klíč k získání výsledku: 
    =COUNTA(UNIQUE(FILTER(A2:A12, A2:A12<>"")))

    Počítejte odlišné hodnoty v Excelu 365/2021 pomocí vzorce vylučte prázdné buňky

Související články:

  • Spočítat jedinečné hodnoty v kontingenční tabulce
  • Ve výchozím nastavení, když vytvoříme kontingenční tabulku založenou na rozsahu dat, který obsahuje některé duplicitní hodnoty, budou se počítat také všechny záznamy, ale někdy chceme jen spočítat jedinečné hodnoty založené na jednom sloupci, abychom získali správné výsledek snímku obrazovky. V tomto článku budu hovořit o tom, jak spočítat jedinečné hodnoty v kontingenční tabulce.
  • Počítejte jedinečné hodnoty ve filtrovaném sloupci
  • Pokud máte seznam jmen, který se ve filtrovaném sloupci naplnil některými duplikáty, a nyní chcete spočítat počet jedinečných jmen pouze z tohoto filtrovaného seznamu. Máte nějaké dobré řešení pro rychlé řešení této úlohy v aplikaci Excel?
  • Počítejte jedinečné hodnoty s více kritérii
  • Zde je řada dat, která obsahují několik jmen, projektů a umístění, a co je třeba udělat, je zjistit jména, která odpovídají kritériím, která mám v seznamu, a poté spočítat jednotlivá shodná jména pouze jednou, jak je ukázáno níže. Máte nějaké triky při řešení této práce? V tomto článku představím triky.
  • Zřetězit jedinečné hodnoty
  • Pokud mám dlouhý seznam hodnot, které se naplnily nějakými duplicitními daty, teď chci najít pouze jedinečné hodnoty a poté je zřetězit do jedné buňky. Jak mohu tento problém rychle a snadno vyřešit v aplikaci Excel?