Jak automaticky označovat e-maily na základě konkrétní přílohy v aplikaci Outlook?

Autor: Xiaoyang Naposledy změněno: 2018-10-22

Když dostáváte některé e-maily se specifickou důležitou přílohou, možná je budete muset odhlásit, abyste je mohli rychle a snadno najít pro rozbalení. V tomto článku budu hovořit o snadném způsobu automatického označování e-mailů s konkrétními jmény.

Automaticky označte e-maily na základě konkrétní přílohy pomocí kódu VBA

Automaticky označte e-maily na základě konkrétní přílohy pomocí kódu VBA

Chcete-li automaticky označit e-maily, které obsahují konkrétní přílohu, použijte následující kód VBA:

1. Spusťte aplikaci Outlook a poté podržte klávesu ALT + F11 klávesy pro otevření Microsoft Visual Basic pro aplikace okno.

2. V Microsoft Visual Basic pro aplikace okno, dvakrát klikněte ThisOutlookSession z Project1 (VbaProject.OTM) v podokně otevřete nový režim a poté zkopírujte a vložte následující kód do prázdného modulu.

Kód VBA: Automaticky označit e-maily na základě konkrétní přílohy:

Public WithEvents GMailItems As Outlook.Items
Private Sub Application_Startup()
    Set GMailItems = Outlook.Application.Session.GetDefaultFolder(olFolderInbox).Items
End Sub

Private Sub GMailItems_ItemAdd(ByVal Item As Object)
    If Item.Class <> olMail Then Exit Sub
    FlagEmail_SpecificAttachments Item
End Sub

Sub FlagEmail_SpecificAttachments(Mail As Outlook.MailItem)
    Dim xAttachment As Outlook.Attachment
    Dim xExt As String
    Dim xFileName As String
    If Mail.Attachments.Count = 0 Then Exit Sub
    For Each xAttachment In Mail.Attachments
        xExt = SplitPath(xAttachment.FileName, 2)
        xFileName = SplitPath(xAttachment.FileName, 1)
        Select Case xExt
            Case "txt", "xlsx", "docx", "pdf"  'Add the file extension as you need
                If InStr(LCase(xFileName), LCase("KTO")) > 0 Then 'Change the text of the attachment name
                    With Mail
                        .ReminderSet = True
                        .ReminderTime = Now + 1
                        .MarkAsTask olMarkTomorrow
                        .Save
                    End With
                End If
        End Select
    Next
End Sub

Public Function SplitPath(FullPath As String, ResultFlag As Integer) As String
Dim xSplitPos As Integer, xDotPos As Integer
xSplitPos = InStrRev(FullPath, "/")
xDotPos = InStrRev(FullPath, ".")
Select Case ResultFlag
    Case 0
        SplitPath = Left(FullPath, xSplitPos - 1)
    Case 1
        If xDotPos = 0 Then xDotPos = Len(FullPath) + 1
        SplitPath = Mid(FullPath, xSplitPos + 1, xDotPos - xSplitPos - 1)
    Case 2
        If xDotPos = 0 Then xDotPos = Len(FullPath)
        SplitPath = Mid(FullPath, xDotPos + 1)
    Case Else
    Err.Raise vbObjectError + 1, "SplitPath Function", "Invalid Parameter!"
End Select
End Function

Poznámka: Ve výše uvedeném kódu můžete podle potřeby změnit příponu souboru a název souboru přílohy.

3. Poté uložte kód a restartujte aplikaci Outlook, aby se kód projevil, nyní při příjmu e-mailů, jejichž názvy příloh obsahují zadaný text, Outlook automaticky nahlásí tento e-mail pro další sledování, viz screenshot: