Jak normálně odpovídat ve složce odeslaných položek z Outlooku? 

Normálně, když kliknete na funkci Odpovědět ve složce Odeslané položky pro odeslání další zprávy pro lidi, které jste odeslali, zobrazí se vaše vlastní e-mailová adresa v poli Komu jako následující snímek obrazovky. To může být nepříjemné pro vás při každé změně adresy. Jak může aplikace Outlook použít adresu původního příjemce, ne vaši?

Normálně odpovídejte ve složce Odeslané položky z Outlooku pomocí funkce Odpovědět všem

Normálně odpovídejte ve složce Odeslané položky z Outlooku pomocí kódu VBA

---

Normálně odpovídejte ve složce Odeslané položky z Outlooku pomocí funkce Odpovědět všem

V Outlooku Odpovědět všem funkce vám pomůže tento problém vyřešit, proveďte toto:

Pokud potřebujete odeslaný e-mail odpovědět a odeslat znovu, abyste si uchovali adresu původního příjemce, klikněte prosím Odpovědět všem tlačítko a adresa původního příjemce je umístěna na Na pole jako následující snímek obrazovky:

---

Normálně odpovídejte ve složce Odeslané položky z Outlooku pomocí kódu VBA

Někdy můžete zapomenout na Odpovědět všem funkce při odpovídání na odeslanou zprávu, takže níže uvedený kód VBA vám pomůže normálně odpovědět ve složce Odeslané položky pomocí funkce Odpovědět. Postupujte podle následujících kroků:

1. Podržte ALT + F11 klávesy pro otevření Microsoft Visual Basic pro aplikace okno.

2. V Microsoft Visual Basic pro aplikace okno, dvakrát klikněte ThisOutlookSession z Project1 (VbaProject.OTM) v podokně otevřete režim a poté zkopírujte a vložte následující kód do prázdného modulu.

Kód VBA: Normálně odpovídejte ve složce Odeslaná pošta z Outlooku:

Option Explicit
Private WithEvents GExplorer As Explorer
Private WithEvents GMailItem As MailItem
Private Sub Application_Startup()
    Set GExplorer = Application.ActiveExplorer
End Sub
Private Sub GExplorer_SelectionChange()
   On Error Resume Next
   Set GMailItem = GExplorer.Selection.Item(1)
End Sub
Private Sub GMailItem_Reply(ByVal Response As Object, Cancel As Boolean)
Dim xResponse As MailItem
Dim xRecipients As Outlook.Recipients
Dim xRecipient As Outlook.Recipient
Dim i As Integer
Dim xTo As String, xCC As String, xBCC As String, xName As String
On Error Resume Next
If Application.ActiveExplorer.CurrentFolder <> Session.GetDefaultFolder(olFolderSentMail) Then
    Exit Sub
End If
Cancel = True
Set xResponse = GMailItem.Reply
Set xRecipients = GMailItem.Recipients
For i = xRecipients.Count To 1 Step -1
    Set xRecipient = xRecipients.Item(i)
    xName = xRecipient.Name
    If Left(xName, 1) = "'" Then
        xName = Mid(xName, 2, Len(xRecipient.Name) - 2)
    End If
    Select Case xRecipient.Type
        Case olTo
            xTo = xName & ";" & xTo
        Case olCC
            xCC = xName & ";" & xCC
        Case olBCC
            xBCC = xName & ";" & xBCC
    End Select
Next
With xResponse
    .To = xTo
    .CC = xCC
    .BCC = xBCC
End With
xResponse.Recipients.ResolveAll
xResponse.Display
End Sub

3. Poté uložte kód a restartujte aplikaci Outlook, aby se efekt kódu projevil hned po kliknutí odpověď znovu odeslat e-mail Odeslané položky složky, zobrazí se podle potřeby adresa původního příjemce v poli Komu.