Jak vytvořit schůzku z dat aplikace Excel?

Autor: Xiaoyang Naposledy změněno: 2018-08-31

Předpokládejme, že máte tabulku dat schůzky v listu aplikace Excel, jak je zobrazeno na následujícím snímku obrazovky, nyní chcete tato data importovat do kalendáře aplikace Outlook. Jak jste se mohli s touto prací rychle vypořádat?

export dat aplikace Excel do schůzky 1

Vytvářejte schůzky z dat aplikace Excel pomocí kódu VBA

Vytvářejte schůzky z dat aplikace Excel pomocí kódu VBA

Chcete-li vytvořit schůzky z dat aplikace Excel, můžete použít následující kód VBA, postupujte takto:

1. Spusťte aplikaci Outlook a podržte ALT + F11 klávesy pro otevření Microsoft Visual Basic pro aplikace okno.

2, klikněte Vložit > Modula vložte následující kód do Modul Okno.

Kód VBA: Importujte data aplikace Excel do schůzky:

Public Sub CreateOutlookApptz()
    Dim xAppointmentItem As Outlook.AppointmentItem
    Dim xNameSpace As Outlook.NameSpace
    Dim xCalendarFld As Outlook.MAPIFolder, xSubFolder As Outlook.MAPIFolder
    Dim xCalendarStr As String
    Dim I As Long
    Dim xFileDialog As FileDialog
    Dim xFilePath As String
    Dim xExcelApp As Excel.Application
    Dim xWb As Workbook
    Dim xWs As Worksheet
    On Error GoTo Err_Execute
    Set xExcelApp = New Excel.Application
    Set xFileDialog = xExcelApp.FileDialog(msoFileDialogFilePicker)
    With xFileDialog
        .Title = "Select a file"
        .Filters.Add "Microsoft Excel", "*.xlsx"
    End With
    If xFileDialog.Show = 0 Then Exit Sub
    xFilePath = xFileDialog.SelectedItems(1)
    Set xWb = xExcelApp.Workbooks.Open(xFilePath)
    Set xNameSpace = Outlook.Application.Session
    Set xCalendarFld = xNameSpace.GetDefaultFolder(olFolderCalendar)
    I = 2
    Set xWs = xWb.Worksheets.Item(1)
    xCalendarStr = xWb.Name
    If FolderExist(xCalendarFld, xCalendarStr) = False Then
        Set xSubFolder = xCalendarFld.Folders.Add(xCalendarStr, olFolderCalendar)
    Else
        Set xSubFolder = xCalendarFld.Folders(xCalendarStr)
    End If
    Do Until Trim(xWs.Cells(I, 1).Value) = ""
        Set xAppointmentItem = xSubFolder.Items.Add(olAppointmentItem)
        With xAppointmentItem
            .Start = xWs.Cells(I, 5) + xWs.Cells(I, 6)
            .End = xWs.Cells(I, 7) + xWs.Cells(I, 8)
            .Subject = xWs.Cells(I, 1)
            .Location = xWs.Cells(I, 2)
            .Body = xWs.Cells(I, 3)
            .BusyStatus = olBusy
            .ReminderMinutesBeforeStart = xWs.Cells(I, 9)
            .ReminderSet = True
            .Categories = xWs.Cells(I, 4)
            .Save
        End With
        I = I + 1
    Loop
    Set xAppointmentItem = Nothing
    Set olApp = Nothing
    xExcelApp.Quit
    Set xExcelApp = Nothing
    MsgBox "Import successfully!", vbInformation, "Kutools for Outlook"
    Exit Sub
Err_Execute:
    MsgBox "An error occurred - Exporting items to Calendar.", vbInformation, "Kutools for Outlook"
End Sub
Function FolderExist(CalFolder As Folder, FolderName As String) As Boolean
    Dim I As Integer
    Dim xSubFolder As Folder
    For I = 1 To CalFolder.Folders.Count
        Set xSubFolder = CalFolder.Folders.Item(I)
        If xSubFolder.Name = FolderName Then
            FolderExist = True
            Exit Function
        End If
    Next I
End Function

3. Stále v Microsoft Visual Basic pro aplikace okno, klepněte na tlačítko Tools > Reference přejděte na Reference-Project1 dialogové okno a zkontrolujte Objektová knihovna Microsoft Excel možnost z nabídky Dostupné reference seznam, viz screenshot:

export dat aplikace Excel do schůzky 2

4. Pak klikněte na tlačítko OK tlačítko, nyní stiskněte F5 klíč ke spuštění tohoto kódu a Vyberte soubor Zobrazí se okno, vyberte soubor aplikace Excel, který chcete importovat do aplikace Outlook, viz screenshot:

export dat aplikace Excel do schůzky 3