Jak zachovat kategorii při odpovídání nebo přeposílání e-mailů v aplikaci Outlook?

Autor: Xiaoyang Naposledy změněno: 2018-11-21

Normálně, když odpovíte nebo přepošlete e-mail, který jsem kategorizoval, bude kategorie automaticky odstraněna z odeslaného e-mailu. Pokud si chcete ponechat kategorii odchozích e-mailů v odpovědích nebo přeposílání, tento článek představí způsob řešení.

Při odpovídání nebo přeposílání e-mailů pomocí kódu VBA udržujte kategorii

Při odpovídání nebo přeposílání e-mailů pomocí kódu VBA udržujte kategorii

1. Podržte stisknuté tlačítko ALT + F11 klávesy pro otevření Microsoft Visual Basic pro aplikace okno.

2. V Microsoft Visual Basic pro aplikace okno, dvakrát klikněte ThisOutlookSession z Project1 (VbaProject.OTM) v podokně otevřete režim a poté zkopírujte a vložte následující kód do prázdného modulu.

Kód VBA: Ponechejte kategorii při odpovídání nebo přeposílání e-mailů:

Private WithEvents GExplorer As Outlook.Explorer
Private WithEvents GInspectors As Outlook.Inspectors
Private WithEvents GMailItem As Outlook.MailItem
Private GCategories As String
Private Sub Application_Startup()
    Dim xApp As Outlook.Application
    Set xApp = Outlook.Application
    Set GExplorer = xApp.ActiveExplorer
    Set GInspectors = xApp.Inspectors
End Sub
Private Sub GExplorer_SelectionChange()
    On Error Resume Next
    If TypeName(GExplorer.Selection.Item(1)) <> "MailItem" Then Exit Sub
    Set GMailItem = GExplorer.Selection.Item(1)
    GCategories = GMailItem.Categories
End Sub
Private Sub GInspectors_NewInspector(ByVal Inspector As Inspector)
    On Error Resume Next
    If TypeName(Inspector.CurrentItem) <> "MailItem" Then Exit Sub
   Set GMailItem = Inspector.CurrentItem
    GCategories = GMailItem.Categories
End Sub
Private Sub GMailItem_Forward(ByVal Forward As Object, Cancel As Boolean)
    Call GetCategories(Forward)
End Sub
Private Sub GMailItem_Reply(ByVal Response As Object, Cancel As Boolean)
    Call GetCategories(Response)
End Sub
Private Sub GMailItem_ReplyAll(ByVal Response As Object, Cancel As Boolean)
    Call GetCategories(Response)
End Sub
Private Sub GetCategories(ByVal NewMail As Object)
    If NewMail.Class <> olMail Then Exit Sub
    NewMail.Categories = GCategories
End Sub

Odpověď na odpověď kategorie 1

3. Poté uložte a zavřete toto okno s kódem, zavřete a restartujte Outlook, nyní, když odpovíte nebo přepošlete e-mail s kategorií, bude kategorie zachována v odchozí zprávě v Odeslané položky, viz screenshot:

Odpověď na odpověď kategorie 2