Jak získat seznam složek v aplikaci Outlook?

Někdy může stromová struktura všech poštovních složek (včetně vytvořených osobních složek) v navigačním podokně uživatelům aplikace Outlook během práce pomoci. Chcete-li rychle zobrazit seznam všech složek stromové struktury, může vám pomoci kód VBA. V tomto kurzu se naučíte, jak snadno získat seznam složek pomocí kódu VBA.

Získejte seznam složek v Outlooku s kódem VBA

Získejte seznam složek v Outlooku s kódem VBA

Seznam složek v Outlooku s kódem VBA získáte následujícím způsobem.

1. zmáčkni Další + F11 na klávesnici otevřete Microsoft Visual Basic pro aplikace okno.

2. Poté poklepejte na ikonu Project1 > Objekt Microsoft Outlook > ThisOutlookSession k otevření Project1 - ThisOutlookSession okno. Viz snímek obrazovky:

3. Poté zkopírujte a vložte níže uvedený kód VBA do okna Project1 - ThisOutlookSession.

VBA: získejte seznam složek v Outlooku

Option Explicit
Sub GetFoldersList()
    On Error GoTo On_Error
    
    Dim Report As String
    Dim Folder As Outlook.Folder
       
    For Each Folder In Application.Session.Folders
        Report = Report & "---------------------------------------------------------------------------" & vbCrLf
        Call RecurseFolders(Folder, "", Report)
    Next
    Call CreateReportEmail("Outlook Folders List", Report)
    
Exiting:
    Exit Sub
On_Error:
    MsgBox "error=" & Err.Number & " " & Err.Description
End Sub
Sub RecurseFolders(CurrentFolder As Outlook.Folder, TabChars, ByRef Report As String)
    Dim SubFolder As Outlook.Folder
    Dim FolderName, StoreName As String
    
    FolderName = CurrentFolder.Name
    StoreName = CurrentFolder.Store.DisplayName
    
    Report = Report & TabChars & FolderName & " (Store: " & StoreName & ")" & vbCrLf
    
    For Each SubFolder In CurrentFolder.Folders
        Call RecurseFolders(SubFolder, TabChars & vbTab, Report)
    Next SubFolder
End Sub
Sub CreateReportEmail(Title As String, Report As String)
    Dim aMail As MailItem
    
    Set aMail = Application.CreateItem(olMailItem)
        
    aMail.Subject = Title
    aMail.Body = Report
    
    aMail.Display
End Sub

4. zmáčkni F5 klávesu na klávesnici spusťte kód VBA.

5. Nyní a Makro objeví se dialogové okno, klikněte prosím na Běh .

6. Počkejte na spuštění makra. Poté se seznam všech vašich e-mailových složek okamžitě zobrazí v okně vytvořené nové zprávy. Můžete jej snadno vytisknout. Viz snímek obrazovky:

Poznámka: Tento kód VBA lze použít pro Outlook 2007, 2010 a 2013.

---

Kutools pro Outlook - přináší do aplikace Outlook 100 pokročilých funkcí a usnadňuje práci!

• Auto CC / BCC podle pravidel při odesílání e-mailů; Automatické předávání Více e-mailů podle zvyku; Automatická odpověď bez serveru Exchange a dalších automatických funkcí ...
• Varování BCC - zobrazit zprávu, když se pokusíte odpovědět všem pokud je vaše e-mailová adresa v seznamu BCC; Připomenout, když chybí přílohya další připomínající funkce ...
• Odpovědět (Vše) Se všemi přílohami v e-mailové konverzaci; Odpovězte na mnoho e-mailů během několika sekund; Automatické přidání pozdravu při odpovědi; Přidat datum do předmětu ...
• Nástroje pro přílohy: Spravujte všechny přílohy ve všech e-mailech, Automatické odpojení, Komprimovat vše, Přejmenovat vše, Uložit vše ... Rychlá zpráva, Počítat vybrané e-maily...
• Výkonné nevyžádané e-maily podle zvyku; Odeberte duplicitní e-maily a kontakty... Umožní vám dělat chytřejší, rychlejší a lepší v Outlooku.

Čtěte více... Stáhnout teď...